Válcové a sférické souřadnice

1. Transformace skalární veličiny do jiných souřadnic

V podstatě je o pouhou substituci, nicméně pomoc počítače se může hodit.
Zejména, pokud navazuje výpočet rozvoje pro velká rm jako v následujících příkladech.

Potenciál dipólu ve směru x

Φ  = p  x/Sqrt[x^2+y^2+z^2]^3
$Assumptions = r>0

TransformedField["Cartesian"->"Spherical",Φ ,{x,y,z}->{r,θ,ϕ}]//FullSimplify

Potenciál pro dva bodové náboje na ose z vyjádřený ve válcových souřadnicích

Φ  = q/Sqrt[x^2+y^2+(z-a)^2]-q/Sqrt[x^2+y^2+(z+a)^2]
$Assumptions = R>0

TransformedField["Cartesian"->"Cylindrical",Φ ,{x,y,z}->{R,ϕ,Z}]//FullSimplify

2. Transformace vektorové veličiny do jiných souřadnic

Zde již nejde o pouhou substituci, je třeba měnit bázová pole

Příklad ze cvičení:  trasformace pole ze sférických do kartézských souřadnic.

f = 2 r^2 LegendreP[2,Cos[θ]] 
A = Grad[ f, {r,θ,ϕ},"Spherical"]

B=TransformedField["Spherical"->"Cartesian",A ,{r,θ,ϕ}->{x,y,z}]//FullSimplify

Příklad ze cvičení:  následuje výpočet divergence v obou souřadnicích

Div[B ,{x,y,z}]

Div[A,{r,θ,ϕ},"Spherical"]//Simplify  (* to "Spherical" je nebytné *)

Bázový vektor (Subscript[e, θ ])vyjádřený v kartézských souřadnicích

TransformedField["Spherical"->"Cartesian",{0,1,0} ,{r,θ,ϕ}->{x,y,z}]//FullSimplify

Další příklady

Potenciál sady stejných nábojů ve vrcholech čtverce o straně 2a.

Φ2 = q  /Sqrt[(x-a)^2+(y-a)^2+z^2]+q /Sqrt[(x+a)^2+(y-a)^2+z^2]+ q  /Sqrt[(x-a)^2+(y+a)^2+z^2]+q /Sqrt[(x+a)^2+(y+a)^2+z^2]
$Assumptions = r>0 && a>0

TransformedField["Cartesian"->"Spherical",Φ2   ,{x,y,z}->{r,θ,ϕ}]//FullSimplify
Series[%,{r,Infinity,6}]//FullSimplify

Potenciál sady stejných nábojů ve vrcholech krychle o hraně 2a.

Φ3  = Sum[ q  /Sqrt[(x-X)^2+(y-Y)^2+(z-Z)^2],{X,-a,a,2a},{Y,-a,a,2a},{Z,-a,a,2a}]
$Assumptions = r>0 && a>0;

TransformedField["Cartesian"->"Spherical",Φ3 ,{x,y,z}->{r,θ,ϕ}]//Simplify;
Φ3a = Series[%,{r,Infinity,10}]//FullSimplify

Co to je za divné funkce v tom rozvoji?

Normal[Φ3a][[2]]
%/.{q->1,a->1,r->1}//Simplify
Maximize[%,{θ,ϕ}][[1]]
SphericalPlot3D[3%+%%,{θ,0,Pi},{ϕ,0,2Pi},PlotRange->Full,PlotPoints->50,PlotLabel->%%]